Foro IRcap

hola tengo una duda de como hacer algo tengo este script
on *:TEXT:*!join*:?: {
{ { //dec %part } { msg $2 ..::••( $nick ha entrado en el torneo. Cupos Disponibles %part )••::.. } }
}

y quiero hacer que cada nick que ponga !join en el privado su nick sea guardado en un txt y tengo otro

on *:TEXT:*!run*:?: {
{ { //inc %part } { msg $2 ..::••( $nick ha abandonado el torneo. Cupos Disponibles %part )••::.. } }
}

y quiero hacer que si un nick lo pone se borre del txt y cuando ponga !participantes salga todos los nombres del txt y si no se puede en txt sea con variables. gracias

Cuál es el cupo para participar?

mira aqui pongo todo el script haber si me puedes ayudar mejor
ON *:TEXT:*!torneo*:?: {
  { set %part $2- }
  amsg 8,1..::••( 8,1Atencion 0Torneo Abierto Organizado por 11PoKeLiFe 0,1Para4 %part 0participantes. Si quieres entrar ponme en un privado !join o si quieres salir pon !run 8)••::..
}

on *:TEXT:*!join*:?: {
  if ( %part == 0 ) { msg $nick 8,1..::••(8 $nick, 0 Lo Sentimos las 4inscripciones 0 para el torneo ya acabaron, Suerte para la proxima 8)••::.. }
  else {
    { { //dec %part } { amsg 8,1..::••(8 $nick 0 ha entrado en el torneo. Cupos Disponibles4 %part 8)••::.. } }
    msg $nick 8,1..::••(8 $nick, 0 Gracias por entrar al torneo de 11 Pokelife, 0 te prometo que no te arrepentiras 8)••::..
    .write inscritos.txt $nick
  }
}

on *:TEXT:*!run*:?: {
  { { //inc %part } { amsg 8,1..::••(8  $nick 0ha abandonado el torneo. Cupos Disponibles4 %part 8)••::..  } }
  msg $nick 8,1..::••(8 $nick, 0 Gracias por participar en el torneo de 11 Pokelife, 0ojala que para la proxima si puedas entrar 8)••::..
  .write -ds $+ $nick inscritos.txt $nick
}

on *:TEXT:*!finish*:?: {
  amsg 8,1..::••(8 Atencion 0Torneo Finalizado por4 $nick 0Razon:4 $2- 8)••::.. 
}

on *:TEXT:*!reglas*:?: {
  amsg 8,1..::••(8 Las Reglas 0del4 Torneo0 son No Ubers, Sleep Clause, Species Clause, No Hax Items (Brightpowder,Quick Claw, Focus Band, King's Rock), Evasion Clause and OHKO Ban 8)••::..
}

on *:TEXT:*!Premio*:?: {
  { set %premio1 $2 }
  { set %premio2 $3 }
  { set %premio3 $4 }
  amsg  8,1..::••( 8Premios:0 Primer Lugar:8 %premio1  0Segundo Lugar:8 %premio2 0Tercer Lugar:8 %premio3 8)••::..
}

on *:TEXT:*!Podium*:?: {
  { set %ganador1 $2 }
  { set %ganador2 $3 }
  { set %ganador3 $4 }
  amsg 8,1..::••( 8Lugares:0 Primer Lugar:8 %ganador1  0Segundo Lugar:8 %ganador2 0Tercer Lugar:8 %ganador3 8)••::..
  amsg 8,1..::••( 8 Enhorabuena 0 Felicidades a los Ganadores, Proximamente otro 4 torneo 0 sigue aqui en 12 Pokelife 8)••::..
  msg %ganador1 8,1..::••( 8 Enhorabuena 0 Has Ganado El Primer Lugar del Torneo de 12 Pokelife, 0 Te Felicito y espero que entres en el siguiente torneo 8)••::..
  msg %ganador2 8,1..::••( 8 Enhorabuena 0 Has Ganado El Segundo Lugar Del Torneo de 12 Pokelife, 0 Te Felicito y espero que entres en el siguiente torneo 8)••::..
  msg %ganador3 8,1..::••( 8 Enhorabuena 0 Has Ganado El Tercer Lugar del Torneo de 12 Pokelife, 0 Te Felicito y espero que entres en el siguiente torneo 8)••::..
  /write fame.txt  8,1..::••( 8Lugares:0 Primer Lugar:8 %ganador1  0Segundo Lugar:8 %ganador2 0Tercer Lugar:8 %ganador3 8)••::..
}

on *:TEXT:*!Primera Ronda*:?:{
  amsg  8,1..::••( 8 Los Pareos 0de la 4Primera Ronda 0son:11 $read(inscritos.txt,1) vs $read(inscritos.txt,8) 8||11 $read(inscritos.txt,3) vs $read(inscritos.txt,6) 8||11 $read(inscritos.txt,5) vs $read(inscritos.txt,7) 8||11 $read(inscritos.txt,4) vs $read(inscritos.txt,2) 8)••::..
}

on *:TEXT:*!Win1*:?:{
  amsg  8,1..::••(8 $2 0ha 11ganado 0su 4batalla0 y pasa a la segunda ronda.8 $3 0ha sido 11eliminado 0del 4torneo 8)••::..
  .write -ds $+ $3 inscritos.txt $3
  msg $3  8,1..::••(8 $3 0has sido 11eliminado 0del 4torneo0 por:8 $2 0Gracias por Participar 8)••::..
}

on *:TEXT:*!Segunda Ronda*:?:{
  amsg  8,1..::••( 8 Los Pareos 0de la 4Segunda Ronda 0son:11 $read(inscritos.txt,1) vs $read(inscritos.txt,3) 8||11 $read(inscritos.txt,2) vs $read(inscritos.txt,4) 8)••::..
}

on *:TEXT:*!Win2*:?:{
  amsg  8,1..::••(8 $2 0ha 11ganado 0su 4batalla0 y pasa a la tercera ronda ronda.8 $3 0ha sido 11eliminado 0del 4torneo 8)••::..
  .write -ds $+ $3 inscritos.txt $3
  msg $3  8,1..::••(8 $3 0has sido 11eliminado 0del 4torneo0 por:8 $2 0Gracias por Participar 8)••::..
}

on *:TEXT:*!Tercera Ronda*:?:{
  amsg  8,1..::••( 8 Los Pareos 0de la 4Ronda Final 0son:8 La Final:11 $read(inscritos.txt,1) vs $read(inscritos.txt,2) 8)••::..
}

on *:TEXT:*!Inscritos*:?: {
  amsg  8,1..::••( 8Los Inscritos 0para el torneo son:4 $read(inscritos.txt,1) $read(inscritos.txt,2) $read(inscritos.txt,3) $read(inscritos.txt,4) $read(inscritos.txt,5) $read(inscritos.txt,6) $read(inscritos.txt,7) $read(inscritos.txt,8) 8)••::..
}

ON *:TEXT:*!HallFame*:*: {
  IF ($2 == $null) {
    msg $chan [RANDOM HALL FAME] $read(fame.txt)
  }
  ELSEIF ($2 isnum) {
    msg $chan [HALL FAME $2 $+ ] $read(fame.txt,$2)

lo hize mediante text pero lo quiero hacer por variables para que sea mas practico creo yo

on *:text:*:?: {
  if ( $strip($1) = !torneo ) { set %users 8
    amsg Atención, torneo abierto organizado por PoKeLiFe para %users participantes. Si quieres entrar ponme en un privado !join o si quieres salir pon !run
  }
  if ( $strip($1) = !join ) {
    if ( !%users ) { msg $nick Usar el comando !torneo para setear la cantidad de participantes | return }
    if ( %users <= 0 ) { msg $nick Lo sentimos las inscripciones para el torneo ya acabaron, suerte para la próxima. }
    else {
      if ( $istok(%participantes,$nick,32) ) { msg $nick Ya estas en la lista. }
      else { dec %users | set %participantes $addtok(%participantes,$nick,32)
        amsg $nick ha entrado en el torneo. $iif(%users,Cupos disponibles %users,Ya no quedan cupos)
        msg $nick Gracias por entrar al torneo de Pokelife, te prometo que no te arrepentirás.
      }
    }
  }
  if ( $strip($1) = !run ) {
    if !%users { msg $nick Usar el comando !torneo para setear la cantidad de participantes | return }
    if !$istok(%participantes,$nick,32) { msg $nick No estas en la lista. }
    else { inc %users | set %participantes $remtok(%participantes,$nick,1,32)
      amsg $nick ha abandonado el torneo. Cupos disponibles %users
    }
  }
  if ( $strip($1) = !finish ) { amsg Atención, torneo finalizado por $nick $+ , Razon $2 | unset %users %participantes }
  if ( $strip($1) = !reglas ) { amsg Las reglas del torneo son: No Ubers, Sleep Clause, Species Clause, No Hax Items (Brightpowder,Quick Claw, Focus Band, King's Rock), Evasion clause and OHKO Ban }
  if ( $strip($1) = !premio ) { amsg Premios: $iif($2,1ºLugar: $2) $iif($3,2ºLugar: $3) $iif($4,3ºLugar: $4) }
  if ( $strip($1) = !podium ) {
    amsg Lugares: $iif($2,1ºLugar: $2) $iif($3,2ºLugar: $3) $iif($4,3ºLugar: $4)
    amsg Enhorabuena, felicidades a los ganadores, próximamente otro torneo, sigue aquí en Pokelife
    $iif($2,msg $2 Enhorabuena has ganado el primer lugar del torneo de Pokelife te felicito y espero que entres en el siguiente torneo.)
    $iif($3,msg $3 Enhorabuena has ganado el segundo lugar del torneo de Pokelife te felicito y espero que entres en el siguiente torneo.)
    $iif($4,msg $4 Enhorabuena has ganado el tercer lugar del torneo de Pokelife te felicito y espero que entres en el siguiente torneo.)
    write fame.txt Lugares: Primer lugar: $2 Segundo lugar: $3 Tercer lugar: $4
  }
  if ( $strip($1) = !inscriptos ) { amsg Los Inscritos para el torneo son: %participantes }
  if ( $strip($1-) = !primera ronda ) { amsg Los pareos de la primera ronda son: $gettok(%participantes,1,32) Vs. $gettok(%participantes,8,32) || $gettok(%participantes,3,32) Vs. $gettok(%participantes,6,32) || $gettok(%participantes,5,32) Vs. $gettok(%participantes,7,32) || $gettok(%participantes,4,32) Vs. $gettok(%participantes,2,32) }
  if ( $strip($1-) = !segunda ronda ) { amsg Los pareos de la segunda ronda son: $gettok(%participantes,1,32) Vs. $gettok(%participantes,3,32) || $gettok(%participantes,2,32) Vs. $gettok(%participantes,4,32) }
  if ( $strip($1-) = !tercera ronda ) { amsg Los pareos de la ronda final son: $gettok(%participantes,1,32) Vs. $gettok(%participantes,2,32) }
  if ( $strip($1) = !win1 ) { set %participantes $remtok(%participantes,$3,1,32)
    amsg $2 ha ganado su batalla y pasa a la segunda ronda. $3 ha sido eliminado del torneo.
    msg $3 has sido eliminado del torneo por: $2 gracias por participar.
  }
  if ( $strip($1) = !Win2 ) { set %participantes $remtok(%participantes,$3,1,32)
    amsg $2 ha ganado su batalla y pasa a la tercera ronda. $3 ha sido eliminado del torneo.
    msg $3 has sido eliminado del torneo por: $2 gracias por participar.
  }
}
on *:text:*!HallFame*:#: {
  if ( !$2 ) { msg # [RANDOM HALL FAME] $read(fame.txt) }
  elseif ( $2 isnum ) { msg $chan [HALL FAME $2 $+ ] $read(fame.txt,$2) }
  else { msg # Comando desconocido }
}
- Saludos -